自定义进度条和自定义属性示例脚本

[@main]

#SAY

\\

自定义装备进度条 <开启/@开启装备进度条> <值+20【带98%触发】/@装备进度条值+> <检测/@检测装备进度条> <取值/@取装备进度条值>\\

自定义装备属性 <开启/@开启装备属性> <值+20/@装备属性值+> <检测/@检测装备属性值> <取值/@取装备属性值>\\

;==============================================================

[@开启装备进度条]

#ACT

; 开启自定义装备进度条0

SETCUSTOMITEMPROGRESSBAR 1 0 0 1

; 设置自定义装备进度条0的名称

SETCUSTOMITEMPROGRESSBAR 1 0 1 刀魂%p-%m:

; 设置自定义装备进度条0的名称

SETCUSTOMITEMPROGRESSBAR 1 0 1 刀魂%r%:

; 设置自定义装备进度条0的颜色

SETCUSTOMITEMPROGRESSBAR 1 0 2 255

; 设置自定义装备进度条0的图片播放张数

SETCUSTOMITEMPROGRESSBAR 1 0 3 15

; 设置自定义装备进度条0上的值按数值方式显示

SETCUSTOMITEMPROGRESSBAR 1 0 4 2

; 设置自定义装备进度条0的大值为 1000

SETCUSTOMITEMPROGRESSBARVALUE 1 0 0 = 1000

; 设置自定义装备进度条0的当前值为 60%

SETCUSTOMITEMPROGRESSBARVALUE 1 0 2 = 60

;==============================================================

[@取装备进度条值]

#ACT

GetCustomItemProgressbarValue 1 0 0 <$STR(N1)>

GetCustomItemProgressbarValue 1 0 1 <$STR(N2)>

GetCustomItemProgressbarValue 1 0 2 <$STR(N3)>

SENDMSG 6 大值<$STR(N1)>

SENDMSG 6 当前值<$STR(N2)>

SENDMSG 6 百分比值<$STR(N2)>%

;==============================================================

[@武器进度条0满98%]

#ACT

SENDMSG 6 ★★★★★★★★进度条满了★★★★★★★★★★。。。。。

[@装备进度条值+]

#IF

CheckCustomItemProgressbarValue 1 0 2 < 100

#ACT

; 设置自定义装备进度条0的当前值+20

SETCUSTOMITEMPROGRESSBARVALUE 1 0 1 + 20

#ELSEACT

BREAK

;判断进度条是否达到98%

#IF

CheckCustomItemProgressbarValue 1 0 2 = 100

#ACT

goto @武器进度条0满98%

;==============================================================

[@检测装备进度条]

#IF

CheckCustomItemProgressbarValue 1 0 2 > 40

#ACT

SENDMSG 6 检测成功

;==============================================================

[@开启装备属性]

#IF

#ACT

SetCustomItemText 1 我的自定义属性显示

SetCustomItemTextColor 1 249

;设置自定义装备属性0的颜色

SetCustomItemAbil 1 0 0 250

;设置自定义装备属性0绑定属性1

SetCustomItemAbil 1 0 1 1

;设置自定义装备属性0的显示位置为1

SetCustomItemAbil 1 0 2 1

;设置自定义装备属性0为百分比显示

SetCustomItemAbil 1 0 3 1

;设置自定义装备属性0的值

SetCustomItemValue 1 0 = 20

;——————————-

;设置自定义装备属性1的颜色

SetCustomItemAbil 1 1 0 249

;设置自定义装备属性1绑定属性2

SetCustomItemAbil 1 1 1 2

;设置自定义装备属性1的显示位置为2

SetCustomItemAbil 1 1 2 2

;设置自定义装备属性1为非百分比

SetCustomItemAbil 1 1 3 0

;设置自定义装备属性1的值

SetCustomItemValue 1 1 = 40

;================================================================

[@装备属性值+]

#ACT

SetCustomItemValue 1 0 + 20

;================================================================

[@检测装备属性值]

#IF

CheckCustomItemValue 1 0 > 100

#ACT

SENDMSG 6 装备属性值0大于100

;================================================================

[@取装备属性值]

#ACT

GetCustomItemValue 1 0 <$STR(N1)> <$STR(N2)>

; 第2个变量不为0时,表示百分比

#IF

Equal <$STR(N2)> 0

#ACT

SENDMSG 6 装备属性值0为<$STR(N1)>

#ELSEACT

SENDMSG 6 装备属性值0为<$STR(N1)>%

声明:本站所有文章,任何个人或组织,在未征得本站同意时,禁止复制、盗用、采集、发布本站内容到任何网站、书籍等各类媒体平台。如若本站内容侵犯了原著者的合法权益,可联系我们(hljlife@vip.qq.com)进行处理。

本站所有资源来源于网络,本站未参与任何dump或hack活动。若有侵犯您的权益请提供相关证明致邮hljlife@vip.qq.com,我将及时撤下该资源。

All resources come from the network, this site does not participate in any dump or hack activities, if there is any violation of your rights, please provide relevant proof and email hljlife@vip.qq.com, I will promptly delete it.

如果下载资源文件后缀为.PDF,请删除后缀.PDF之后运行。

部分失效链接可通过文末填写有效邮箱到Email输入框留言索取。

免责声明:游戏资源均来自网络收集购买,不保证BUG,不保证病毒,不解答游戏问题(传奇服务端提供付费架设服务),为了安全,请尽量选择虚拟机运行服务端。